Filename: trucks-7.*; Abstract: trk-abs.txt

Reference: MATHEMATICS AND
       COMPUTERS IN SIMULATION 51 (February 2000):1-17.

Abstract

This study develops a Maple worksheet for experimenting with truck transportation, with incentives for speeding, and with the efficacy of various ways of controlling speeding. The model suggests that the total cost function, operating as a feedback mechanism, may influence a truck driver's incentives for speeding and/or a firm's incentives for encouraging or discouraging speeding.

Introduction

Reading \cite{Ouel94}, we learn that the typical trucker logs 60 to 70 hours per week; that he or she works ``at a steady clip" whether paid by the hour or by the load; that there are many subtle pressures that lead to excessive speed, e.g., ``drivers often jockey one another for position on the road and by the loading dock, as a minute or two lead to the next job ... can save an hour or two of waiting time." All of which leads us to seek circumstances under which a speed in excess of 65 to 70 miles per hour would appear to be rational. Here, rational means cost-minimizing, or profit-maximizing. In addition, we ask how law enforcement authorities would attempt to manipulate these circumstances in order to bring about acceptable compliance with speed limits.

The following Maple commands clear a worksheet and introduce a measure of the amount of processor time required to run this model. The result appears at the end of the article.

> restart;

> job := time():

Structure

First we insert a baseline operating cost, in dollars per mile, for a given type of truck. By baseline, we mean all costs involved in paying for and maintaining a truck, worked out on a per-mile basis, but without considering ways in which costs are raised by driver behavior, e.g., high operating speeds, mechanical abuse, etc., or by traffic citations.

Standard cost per mile, in dollars:

> k1 := 1/3;

Truck operating costs increase with average speed, due especially to increased fuel consumption and increased depreciation. We estimate this additional cost, per mile, to be a certain multiplier of a dollar: the speed in m.p.h., called , which we first adjust with an exponent and then divide by, say, 1000 or some other large standard:

> p := 8/5; k17 := 4*(10^3);

We then define as an additional cost factor,

which evaluates as follows:

> x[1] := (v^p)/k17; # additional velocity cost factor

We consider the situation of drivers who have an hourly pay rate; such drivers, according to Ouellet, are in a very different situation from those who receive piece-work payment. The hourly wage, defined below, assumes that for at least part of a lengthy trip two drivers must be paid, so that the value assigned to is a weighted average:

> k3 := 3715/100; # drivers' hourly wage

The trip length is 600 miles.

> k4 := 600; # trip length, miles

A provisional total cost for trips of this type has two components, as in a Cobb-Douglas function (Dowling 1990:213-14): capital cost and labor cost. The first component, , is the cost of the non-labor component. It is the length of the trip, , multiplied by the sum of and , where , as defined above, is the fixed operating cost per mile and is the additional cost factor related to speed:

> cn := k4*(k1 + x[1]); # non-labor cost, complete trip

The second cost factor, the labor component , is the driver's hourly wage multiplied by the amount of time required for the trip, where the latter is trip length divided by speed, :

> cl := k3*(k4/v); # labor cost, complete trip

Now we can examine non-labor costs and labor costs together, as functions of speed, on a single plot (Figure 1). Costs are minimized at a speed for which non-labor costs are at the same rate as labor costs are . Derivatives ``cancel out" at the speed that minimizes the cost of trips of this type.

> plot({cn, cl}, v = 50..90, thickness = 3,\
labels = [speed, cost],\
title = `Fig. 1: cn and cl as function of speed`);

Finally we obtain the total cost function for this particular trip, , defined as the sum of and , non-labor and labor costs respectively:

> ct := cn + cl; #total cost, complete trip

We now plot the cost as a function of speed (Figure 2):

> plot(ct, v = 50..90, thickness = 3,\
labels = [speed, cost],\
title = `Fig. 2: Total cost as function of speed`);

The various expressions defined above---the values and the variable for ``additional velocity" costs---are the most important structural feature of this model. There are many combinations of these values which, although realistic enough, do not have steep slopes or interesting minimizations, i.e., slopes and minima that might create incentives for driving dangerously fast. One may find it necessary to run many experiments in order to arrive at a configuration with interesting and realistic structural properties. A major task of empirical investigations, then, would be to ascertain the frequency of dangerous speed-inducing configurations in the real world (see Section A.1).

Eventually, empirical tests should be conducted to determine the sorts of speed-inducing incentive structures that actually exist in a given sector of the trucking industry, but the purpose of the present exercise is to develop a large family of logical possibilities that generate a consistent predictive logic. In the analysis that unfolds below, for instance, we arrive at predictions about the circumstances under which truckers would be tempted to increase speed, or the circumstances under which sanctions against speeding would have a strong prospect of being effective, or the circumstances under which the probability of sanctions would be more important than their severity. The basic underlying model captures the abstract dynamics of the Coleman/Stinchcombe formulation (Coleman, 1968:440; Stinchcombe, 1968:89; Faia, 1986, Ch. 5) involving the interaction of disequilibria and adaptations thereto.

Dynamics

In order to analyze the socio-ecological dynamics of truck-transportation, we need to find the speed that minimizes total costs; this speed is often high---over 80 m.p.h. in our initial model---and it is sometimes considerably higher than that.

The derivative for the total cost function, ct, with regard to speed is

> Diff(ct, v) = diff(ct, v);

and we obtain the total-cost minimum by setting this derivative to zero:

> sol1 := solve(diff(ct, v) = 0, v):

The cost-minimizing speed, then, is slightly in excess of 80 m.p.h.

> sol1[1]; evalf(%,4);

Perhaps more realistically, one could ask how much incentive there would be to increase one's speed from, say, 60 or 70 m.p.h. to any given higher level. That is, how much would costs for each trip drop for each mile-per-hour added to one's speed, starting at a relatively safe speed? Here, we need to evaluate the derivative for speeds such as and . Adjacent values may be substituted:

> k5 := 60: k6 := 70:

> subs(v = k5, diff(ct, v)): evalf(%, 3);\
subs(v = k6, diff(ct, v)): evalf(%, 3);

These solutions imply that there is a strong incentive for going faster than 60 m.p.h.---$3.38 can be shaved from the cost for each additional mile per hour---and that this incentive declines considerably as one approaches what we will soon define as the de facto speed limit. Once familiar with this basic model, it is possible to run experiments by changing various initial values, or the variable . Slopes typically would change, and so would the relative importance of various cost components.

For the remainder of this paper we shall assume that, given the cost structure as defined heretofore and as shown in the total-cost function, there is little incentive for increasing speed beyond 85 m.p.h. or so. An upper boundary of 90 m.p.h. will be assumed for the following analyses.

Adaptation and Social Control

In this example, it appears that the tendency to race for loading docks, as described by Ouellet, could be used by unscrupulous firms as a way of reducing costs: Any factor that causes drivers to increase speed toward the minimal-cost level, when it is high, may reduce costs for the trucking firm by reducing hourly wages and by reducing idle time at loading docks. Suppose, however, that these cost-reduction strategies tend to get drivers and firms into trouble with the police and highway patrol. This contingency adds to costs. We can estimate these costs on a miles-per-hour basis for all speeds in excess of what we might call the de facto speed limit---the speed where the police start writing tickets. We shall try to ascertain what sort of sanction system is likely to bring about significant speed reductions. For now, there are two decisions about the sanction system: First, what is the probability of a speeding citation on a given trip, when one exceeds the de facto speed limit? Second, what is the severity of the sanction, that is, the cost of speeding citations for each m.p.h. in excess of the de facto limit?

Social scientists who write about deterrence usually distinguish among four aspects of punishment: probability, severity, celerity (speed of delivery of sanctions), and saliency (awareness of prior warnings or prior instances of punishment). How could all four of these factors be written into a model? What is the relative impact of, say, a 10 per cent increase in the probability of punishment versus a plausible increase in the severity of it?

Sanctions

We begin working toward a resolution of these problems by writing a new cost function, one that will take into account our costs as already established and will also allow for increased costs due to traffic citations. Initially, we assume a fixed probability for traffic citations, regardless of the degree to which speed exceeds the de facto speed limit. The assumption is based on the idea that excessive speeders use all sorts of tactics to avoid detection, including radio communication, headlight signals, radar detectors, a watchful eye while passing through known ``speed traps," and so forth. Again, this raises the issue of the relationship between the probability and severity of sanctions: High severity, when it is salient, probably increases the use of these tactics.

The following series of k values sets up the first of several experiments on the impact of sanction systems. The value k7 = 1/10 is the probability of receiving a citation on a given trip; the value k8=9 assumes that the cost of citations is proportional to the excess of speed over the speed limit; the value k9=75 refers to the de facto speed limit within a given jurisdiction, i.e., the speed at which k7 becomes a factor because the police begin writing citations.

> k7 := 1/10: # probability of receiving a speeding ticket

> k8 := 9: # sanction severity:\
# cost of speeding ticket, for each m.p.h. excess

> k9 := 75: # the de facto speed limit

We now obtain a new cost factor cc, defined as the probability of receiving a citation k7 multiplied by sanction severity k8, with the latter multiplied by excess speed in miles per hour:

> cc := k7*k8*(v - k9);

Next we calculate an extended total cost function, ctt, defined as the sum of non-labor costs cn, labor costs cl, and citation costs cc:

Using the appropriate Maple command, we make substitutions:

> ctt := cn + cl + cc; # total cost,\
# including impact of sanction system

And a plot (Figure 3) showing excess operating costs due to the current sanction system, i.e., sanction system I:

> plot({ct, ctt}, v = k9..90, thickness = 3, labels = [speed, cost],\
title = `Fig. 3: Excess operating costs, sanction system I`);

How effective is our sanction system at this point? If the region located between these two curves, and ranging from the de facto speed limit upward to, say, 90 m.p.h., were considered a ``braking factor," then we could integrate through the region as a way of assessing the weight of this factor.

We begin by reducing output to seven digits:

> Digits := 7:

Next, we integrate the total cost function ctt, including sanctions, from k9=75 m.p.h. up to 90 m.p.h., defining the result as i. Then we integrate the total cost function ct, excluding sanctions, also from k9=75 m.p.h. to 90 m.p.h., and define the result as j. Finally, the variable weight is defined as the difference between i and j. In the several experiments following, variables such as ctt and k9 are modified, and a few new variables are introduced.

> Int(ctt, v = k9..90) = int(ctt, v);\
i := int(ctt, v = k9..90):

Evaluating this result for , we have

> evalf(%, 6);

and, next, the same calculations for , setting the result equal to :

> Int(ct, v = k9..90) = int(ct, v);\
j := int(ct, v = k9..90): evalf(%, 6);

Here we obtain :

> weight := i - j; evalf(%, 5);

This does not seem to be a very heavy weight, but all is relative. How could we make it heavier? What is the relative impact of sanction probability and sanction severity on the braking factor? In a later section, we shall interpret as a factor that would cause drivers to slow down even in situations where the weight of sanctions has not been increased.

Ouellet implies that various ways of organizing the work of truck drivers would have an impact on the dynamics built into the above model. Hourly wage scales are not the only factor making for excess speed. In particular, non-union truckers paid on a piece-rate system also appear to have strong time pressures and especially strong incentives for speeding (Ouellet, 1994:29,44). A few companies demand that drivers observe the speed limit (1994:33), and some companies use tachographs to record speeds. But Ouellet presents evidence suggesting that work pressures often overcome these rules (1994:44, 47, 48-49, 62, 69):
 

Some [drivers] exceeded the speed limit almost constantly, often at gross levels ..., and did so at night when it is difficult to spot police. ... The paradox here is that speeding [under the hourly pay system] had the effect of reducing pay while inviting expensive citations by the police, and accumulating several of these could result in license suspension (Ouellet, 1994:70).

Non-union drivers often do not have the job protections afforded their unionized counterparts; they therefore tend to speed if there are pressures to do so, and they also tend to have more accidents and to receive many citations. ``In effect [due to poor safety records, etc.], the organization of work in the competitive [non-union] sector tends, over a period of time, to lock the driver into both that sector and its second-rate companies" (Ouellet, 1994:163). Finally, drivers often believe that police harass them for unfair reasons, e.g., working for a small company or being owner-operators themselves.

Ouellet shows that there are many factors that influence a given driver's decisions about speed: the type of company for which a driver works (including self-employment), the company's policies regarding speed, whether the driver is paid on a piece rate or by the hour, the dynamics of ``racing" toward loading docks, the conduct of law enforcement, etc. And there are some interesting paradoxes: For instance, the piece-rate plan is often a method for inducing workers to work faster, whereas an hourly rate tends to slow them down. An hourly rate, however, may give management an incentive for finding unique ways of inducing greater speed on the part of drivers who might otherwise remain reluctant. Many of Ouellet's factors should be included in more complete models.

If the police discriminate against certain types of truckers, we should be able to capture this practice mathematically by modifying the following processes, which we have simply copied from above. For instance, one might assume that discrimination occurs in instances where the police arbitrarily lower the de facto speed limit . Suppose it were lowered to m.p.h. What would be the consequences?

> k9 := 70: # the new, discriminatory de facto speed limit

> cc := k7*k8*(v - k9);

> ctt := cn + cl + cc; # new total cost,\
allowing for discrimination\
# and including impact of sanction system

A plot (Figure 4) suggests that costs will be raised significantly:

> plot({ct, ctt}, v = k9..90, thickness = 3, labels = [speed, cost],\
title = `Fig. 4: Excess operating costs, sanction system II`);

> Int(ctt, v = k9..90) = int(ctt, v);\
i := int(ctt, v = k9..90): evalf(%, 6);

> Int(ct, v = k9..90) = int(ct, v);\
j := int(ct, v = k9..90): evalf(%, 6);

> weight := i - j;

Although it is weightier, this sanction system, unlike that depicted in Figure 3, does not create an upward acceleration of costs until speed reaches a level that is well in excess of the de facto speed limit. This may reduce the efficacy of the system, despite the fact that it involves discrimination by law enforcement that may have been intended to bring about substantial reductions of speed by enhancing the salience of a relatively low de facto limit. In this instance, then, a discriminatory raising of law-enforcement standards may have a double impact: It may increase the salience of sanctions while at the same time inducing a higher rate of deviance. The next modification of the sanction system appears to overcome this deficiency.

The expressions (sanction probability) and (sanction severity) should be thought of as scores for factors to which we can attach weights, as in regression analysis. In the equation for the cost of citations, , the probability and severity of sanctions are multiplied by each other, and then this product is multiplied by the degree to which speed exceeds the de facto limit. In running experiments one might assume, for instance, that for a given amount of funding a law-enforcement agency could raise the severity of sanctions by, say, 15 per cent, or the probability of sanctions by, say, 5 per cent. If has an impact on the subjective salience of the sanction system among drivers, then one might conclude that raising fines by 15 per cent would have greater deterrent value than raising the probability of citations by 5 per cent. However, may have little utility as a predictor of subjective awareness of sanctions.

One way to make the sanction system more realistic would be to allow the probability of citations to vary with speed (up to, say, 90 m.p.h.). A new variable, , is defined by writing a maximum value for citation probability, 7/10, and then multiplying this value by excess speed, , as a proportion of the range from the de facto speed limit to the maximum feasible speed, 90 m.p.h.:

We plot x[2] against speed (Figure 5) to make sure that it behaves as a probability---ranging from 0 to 7/10---within the appropriate range for :

> k8 := 9: # sanction severity

> k9 := 75: # the de facto speed limit

> x[2] := (7/10)*(1 - ((90 - v)/(90 - k9)));\
# probability of receiving a speeding ticket, for any given trip

> plot(x[2], v = 75..90, thickness = 3, labels = [speed, prob],\
title = `Fig. 5: Probability of sanctions by speed`);

Now, we write a modified equation for , substituting for , as follows:

> cc := x[2]*k8*(v - k9);

Substitute the new value for cc into ctt:

> ctt := cn + cl + cc;\
# total cost, including impact of sanction system, as modified

Finally, a new plot (Figure 6):

> plot({ct, ctt}, v = k9..90, thickness = 3, labels = [speed, cost],\
title = `Fig. 6: Excess operating costs, sanction system III`);

> Int(ctt, v = k9..90) = int(ctt, v);\
i := int(ctt, v = k9..90): evalf(%, 6);

> Int(ct, v = k9..90) = int(ct, v);\
j := int(ct, v = k9..90): evalf(%, 6);

> weight := i - j; evalf(%, 5);

If the preceding equation for captures the objective (and perhaps subjective) dimensions of the sanction system as it impinges on speeding, then the values obtained for sanction weight might lead us to predict that, contrary to what we often observe regarding the relative importance of sanction probability and severity, in this instance severity is likely to have the larger impact. This is due to the fact that, other things equal, it may be much easier to make objective changes in sanction severity than in sanction probability, i.e., severity may have greater elasticity. If violators of traffic laws tend to play highly rational games with law enforcement (Chambliss, 1966; Gibbs, 1975; Nettler, 1976), it is possible that such violators would be far more responsive to feasible changes of sanction severity than to feasible changes of sanction probability.

Another factor that influences the relative impact of sanction probability and severity is that, in many instances, an increase in severity brings about a decrease in probability, because the judicial system is reluctant to impose weightier sanctions. It is as if there were a negative correlation between severity and probability, such that, for instance, the following regression equation would be appropriate:

The regression weight 3/10 assumes that sanction severity has greater elasticity than sanction probability.

> prbmult := 1 - (3/10)*(sevmult - 1);

We define next a pair of values for use in the following experiment. As a check, one might compare these values against Figure 8, found in A.2:

> sevmult := 2.2;

> prbmult;

It is now feasible to experiment with variations in probability and severity of sanctions, as follows. First, we collect some earlier terms:

> k8 := 9; # sanction severity:
# cost of speeding ticket, for each m.p.h. excess

> k9 := 75; # the de facto speed limit

> x[2] := (7/10)*(1 - ((90 - v)/(90 - k9)));
# probability of receiving a speeding citation, for any given trip

Next, we write a new equation for , incorporating the correlation between probability and severity of sanctions (see Section A.2),

and then we substitute this equation into ctt:

> cc := prbmult*x[2]*sevmult*k8*(v - k9);

> ctt := cn + cl + cc;\
# total cost, including impact of sanction system

And another plot (Figure 7), followed by the usual calculation for sanction weight:

> plot({ct, ctt}, v = k9..90, thickness = 3,labels = [speed, cost],\
title = `Fig. 7: Excess operating costs, sanction system IV`);

> Int(ctt, v = k9..90) = int(ctt, v);\
i := int(ctt, v = k9..90): evalf(%, 6);

> Int(ct, v = k9..90) = int(ct, v);\
j := int(ct, v = k9..90): evalf(%, 6);

> weight := i - j: evalf(%, 5);

Experiments show that, for sanction system IV, if the multiplier for sanction severity is 1, thereby maximizing the probability of sanctions, then sanction weight is 472 (as in the preceding section). As sanction severity is raised still further, sanction weight increases to a maximum that is around 665 when the severity multiplier is set at 2.2 (and the probability multiplier becomes .64), but it then declines to a value of 374 when sanction severity is multiplied by 3.6 (and the probability of sanctions drops accordingly). The strategy of increasing the severity of sanctions, then, eventually may become counterproductive. Examining the same pattern from right to left, we would note that an increasing probability of sanctions would raise the overall weight of sanctions (Sherman and Berk, 1984), but after this probability had moved through the zone of maximum efficacy we would again observe a decline in efficacy. Thus, one might conclude that if there is a u-shaped curve for the size of prison populations relative to severity of prison sentences (Clark and Lee, 1996), then there is probably also such a curve, with an inverted u shape, for the impact of sanctions with differing severity.

Processor Time

The variable called , defined near the top of this program, copies one's computer clock time between the beginning and the end of an experiment; the following command merely subtracts the beginning clock time from the ending clock time. Repeat this command below, following further experiments as desired.

> time() - job;

Appendix:

(A.1) Transportation technology develops rapidly, and it is entirely possible that the global positioning system (GPS) will add substantial flexibility to the structural conditions defined in this paper. To cite one possibility, the GPS may give dispatchers the ability to suggest speed changes to drivers at frequent intervals. It is this sort of rapid adjustment---concurrent feedback with high frequency of change and perhaps low amplitude---that enables a few airline pilots to make transcontinental flights in which they save several thousands of dollars in fuel.

For an illustration of the way in which Joe DiMaggio's record for consecutive games with at least one base hit may have been influenced by concurrent feedback, see Lieberson (1997:15-16).

(A.2) The regression line that corresponds to this correlation has the following properties: (a) it passes through the point and ; (b) with defining the ordinate (Figure 8), the line has a slight downward slope reflecting the assumption that has greater elasticity than ; (c) usable scores for start at about .2, and it seems plausible that their highest value would impose a value of .2 on , with results as follows:

> prbmult := 'prbmult': sevmult := 'sevmult':
# Re-initialize variables

> prbmult := 1 - (3/10)*(sevmult - 1);

> subs(sevmult = 2, prbmult); # Substitute value

> solve({prbmult = 1 - (3/10)*(sevmult - 1),
prbmult = 2/10}, sevmult); # Substitute value;

> evalf(%, 3);

Figure 8 shows the probability multiplier as a function of the severity multiplier:

> plot(prbmult, sevmult=-1..5, thickness=3,\
title = `Fig. 8: Probability multiplier by severity multiplier`,\
labels = [sevmult, prb]);

In our own experiments, sevmult ranges from 1 to 3.6.

Filename: bin\trucks-7.bib

REFERENCES:

Chambliss, William J. 1966. ``The deterrent influence of punishment." Crime and Delinquency 12:70-75.

Clark, J. R. and Dwight R. Lee. 1996. ``Sentencing Laffer curves, political myopia, and prison space." Social Science Quarterly 77: 245-72.

Coleman, James S. 1968. ``The mathematical study of change." Pp. 428-78 in Hubert M. Blalock and Ann B. Blalock, editors. Methodology in Social Research. New York: McGraw-Hill.

Dowling, Edward T. 1990. Calculus for Business, Economics, and the Social Sciences. New York: McGraw-Hill.

Faia, Michael A. 1986. Dynamic functionalism: Strategy and tactics. New York: Cambridge University Press.

Gibbs, Jack P. 1975. Crime, Punishment, and Deterrence. New York: Elsevier.

Lieberson, Stanley. 1997. ``Modeling social processes: Some lessons from sports." Sociological Forum 12:11-35.

Nettler, Gwynn. 1976. Social Concerns. New York: McGraw-Hill.

Ouellet, Lawrence J. 1994. Pedal to the Metal. Philadelphia: Temple University Press.

Sherman, Lawrence W. and Richard A. Berk. 1984. ``The specific deterrent effects of arrest for domestic assault." American Sociological Review 49:261-72.

Stinchcombe, Arthur L. 1968. Constructing Social Theories. New York: Harcourt Brace.